Genus

AUTHORS:

  • David Kohel & Gabriele Nebe (2007): First created
  • Simon Brandhorst (2018): various bugfixes and printing
  • Simon Brandhorst (2018): enumeration of genera
sage.quadratic_forms.genera.genus.Genus(A, factored_determinant=None)

Given a nonsingular symmetric matrix \(A\), return the genus of \(A\).

INPUT:

  • A – a symmetric matrix with integer coefficients
  • factored_determinant – (default: None) a factorization object the factored determinant of A

OUTPUT:

A GenusSymbol_global_ring object, encoding the Conway-Sloane genus symbol of the quadratic form whose Gram matrix is \(A\).

EXAMPLES:

sage: A = Matrix(ZZ, 2, 2, [1,1,1,2])
sage: Genus(A)
Genus of
[1 1]
[1 2]
Signature:  (2, 0)
Genus symbol at 2:    [1^2]_2

sage: A = Matrix(ZZ, 2, 2, [2,1,1,2])
sage: Genus(A, A.det().factor())
Genus of
[2 1]
[1 2]
Signature:  (2, 0)
Genus symbol at 2:    1^-2
Genus symbol at 3:     1^-1 3^-1
class sage.quadratic_forms.genera.genus.GenusSymbol_global_ring(signature_pair, local_symbols, representative=None, check=True)

Bases: object

This represents a collection of local genus symbols (at primes) and signature information which represent the genus of a non-degenerate integral lattice.

INPUT:

  • signature_pair – a tuple of two non-negative integers
  • local_symbols – a list of Genus_Symbol_p_adic_ring` instances sorted by their primes
  • representative – (default: None) integer symmetric matrix; the gram matrix of a representative of this genus
  • check – (default: True) a boolean; checks the input

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import GenusSymbol_global_ring, LocalGenusSymbol
sage: A = matrix.diagonal(ZZ, [2,4,6,8])
sage: local_symbols = [LocalGenusSymbol(A, p) for p in (2*A.det()).prime_divisors()]
sage: G = GenusSymbol_global_ring((4,0),local_symbols, representative=A);G
Genus of
[2 0 0 0]
[0 4 0 0]
[0 0 6 0]
[0 0 0 8]
Signature:  (4, 0)
Genus symbol at 2:    [2^-2 4^1 8^1]_6
Genus symbol at 3:     1^3 3^-1

See also

Genus() to create a GenusSymbol_global_ring from the gram matrix directly.

det()

Return the determinant of this genus, where the determinant is the Hessian determinant of the quadratic form whose Gram matrix is the Gram matrix giving rise to this global genus symbol.

OUTPUT:

an integer

EXAMPLES:

sage: A = matrix.diagonal(ZZ, [1,-2,3,4])
sage: GS = Genus(A)
sage: GS.determinant()
-24
determinant()

Return the determinant of this genus, where the determinant is the Hessian determinant of the quadratic form whose Gram matrix is the Gram matrix giving rise to this global genus symbol.

OUTPUT:

an integer

EXAMPLES:

sage: A = matrix.diagonal(ZZ, [1,-2,3,4])
sage: GS = Genus(A)
sage: GS.determinant()
-24
dim()

Return the dimension of this genus.

EXAMPLES:

sage: A = Matrix(ZZ, 2, 2, [1,1,1,2])
sage: G = Genus(A)
sage: G.dimension()
2
dimension()

Return the dimension of this genus.

EXAMPLES:

sage: A = Matrix(ZZ, 2, 2, [1,1,1,2])
sage: G = Genus(A)
sage: G.dimension()
2
discriminant_form()

Return the discriminant form associated to this genus.

EXAMPLES:

sage: A = matrix.diagonal(ZZ, [2,-4,6,8])
sage: GS = Genus(A)
sage: GS.discriminant_form()
Finite quadratic module over Integer Ring with invariants (2, 2, 4, 24)
Gram matrix of the quadratic form with values in Q/2Z:
[ 1/2    0    0    0]
[   0  3/2    0    0]
[   0    0  7/4    0]
[   0    0    0 7/24]
sage: A = matrix.diagonal(ZZ, [1,-4,6,8])
sage: GS = Genus(A)
sage: GS.discriminant_form()
Finite quadratic module over Integer Ring with invariants (2, 4, 24)
Gram matrix of the quadratic form with values in Q/Z:
[ 1/2    0    0]
[   0  3/4    0]
[   0    0 7/24]
is_even()

Return if this genus is even.

EXAMPLES:

sage: G = Genus(Matrix(ZZ,2,[2,1,1,2]))
sage: G.is_even()
True
local_symbols()

Return a copy of the list of local symbols of this symbol.

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import Genus
sage: A = matrix.diagonal(ZZ, [2,-4,6,8])
sage: GS = Genus(A)
sage: GS.local_symbols()
[Genus symbol at 2:    [2^-2 4^1 8^1]_4,
 Genus symbol at 3:     1^-3 3^-1]
signature()

Return the signature of this genus.

The signature is \(p - n\) where \(p\) is the number of positive eigenvalues and \(n\) the number of negative eigenvalues.

EXAMPLES:

sage: A = matrix.diagonal(ZZ, [1,-2,3,4,8,-11])
sage: GS = Genus(A)
sage: GS.signature()
2
signature_pair()

Return the signature pair \((p, n)\) of the (non-degenerate) global genus symbol, where p is the number of positive eigenvalues and n is the number of negative eigenvalues.

OUTPUT:

a pair of integers \((p, n)\) each \(>= 0\)

EXAMPLES:

sage: A = matrix.diagonal(ZZ, [1,-2,3,4,8,-11])
sage: GS = Genus(A)
sage: GS.signature_pair()
(4, 2)
signature_pair_of_matrix()

Return the signature pair \((p, n)\) of the (non-degenerate) global genus symbol, where p is the number of positive eigenvalues and n is the number of negative eigenvalues.

OUTPUT:

a pair of integers \((p, n)\) each \(>= 0\)

EXAMPLES:

sage: A = matrix.diagonal(ZZ, [1,-2,3,4,8,-11])
sage: GS = Genus(A)
sage: GS.signature_pair()
(4, 2)
class sage.quadratic_forms.genera.genus.Genus_Symbol_p_adic_ring(prime, symbol, check=True)

Bases: object

Local genus symbol over a p-adic ring.

The genus symbol of a component \(p^m A\) for odd prime \(= p\) is of the form \((m,n,d)\), where

  • \(m\) = valuation of the component
  • \(n\) = rank of A
  • \(d = det(A) \in \{1,u\}\) for a normalized quadratic non-residue \(u\).

The genus symbol of a component \(2^m A\) is of the form \((m, n, s, d, o)\), where

  • \(m\) = valuation of the component
  • \(n\) = rank of \(A\)
  • \(d\) = det(A) in \(\{1,3,5,7\}\)
  • \(s\) = 0 (or 1) if even (or odd)
  • \(o\) = oddity of \(A\) (= 0 if s = 0) in \(Z/8Z\)
    = the trace of the diagonalization of \(A\)

The genus symbol is a list of such symbols (ordered by \(m\)) for each of the Jordan blocks \(A_1,...,A_t\).

Reference: [Co1999] Conway and Sloane 3rd edition, Chapter 15, Section 7.

Warning

This normalization seems non-standard, and we should review this entire class to make sure that we have our doubling conventions straight throughout! This is especially noticeable in the determinant and excess methods!!

INPUT:

  • prime – a prime number
  • symbol – the list of invariants for Jordan blocks \(A_t,...,A_t\) given as a list of lists of integers
canonical_symbol()

Return (and cache) the canonical p-adic genus symbol. This is only really affects the \(2\)-adic symbol, since when \(p > 2\) the symbol is already canonical.

OUTPUT:

a list of lists of integers

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import p_adic_symbol
sage: from sage.quadratic_forms.genera.genus import Genus_Symbol_p_adic_ring

sage: A = Matrix(ZZ, 2, 2, [1,1,1,2])
sage: p = 2
sage: G2 = Genus_Symbol_p_adic_ring(p, p_adic_symbol(A, p, 2)); G2.symbol_tuple_list()
[[0, 2, 1, 1, 2]]
sage: G2.canonical_symbol()
[[0, 2, 1, 1, 2]]

sage: A = Matrix(ZZ, 2, 2, [1,0,0,2])
sage: p = 2
sage: G2 = Genus_Symbol_p_adic_ring(p, p_adic_symbol(A, p, 2)); G2.symbol_tuple_list()
[[0, 1, 1, 1, 1], [1, 1, 1, 1, 1]]
sage: G2.canonical_symbol()   ## Oddity fusion occurred here!
[[0, 1, 1, 1, 2], [1, 1, 1, 1, 0]]

sage: A = DiagonalQuadraticForm(ZZ, [1,2,3,4]).Hessian_matrix()
sage: p = 2
sage: G2 = Genus_Symbol_p_adic_ring(p, p_adic_symbol(A, p, 2)); G2.symbol_tuple_list()
[[1, 2, 3, 1, 4], [2, 1, 1, 1, 1], [3, 1, 1, 1, 1]]
sage: G2.canonical_symbol()   ## Oddity fusion occurred here!
[[1, 2, -1, 1, 6], [2, 1, 1, 1, 0], [3, 1, 1, 1, 0]]

sage: A = Matrix(ZZ, 2, 2, [2,1,1,2])
sage: p = 2
sage: G2 = Genus_Symbol_p_adic_ring(p, p_adic_symbol(A, p, 2)); G2.symbol_tuple_list()
[[0, 2, 3, 0, 0]]
sage: G2.canonical_symbol()
[[0, 2, -1, 0, 0]]


sage: A = DiagonalQuadraticForm(ZZ, [1,2,3,4]).Hessian_matrix()
sage: p = 3
sage: G3 = Genus_Symbol_p_adic_ring(p, p_adic_symbol(A, p, 2)); G3.symbol_tuple_list()
[[0, 3, 1], [1, 1, -1]]
sage: G3.canonical_symbol()
[[0, 3, 1], [1, 1, -1]]

Note

See [Co1999] Conway-Sloane 3rd edition, pp. 381-382 for definitions and examples.

Todo

Add an example where sign walking occurs!

compartments()

Compute the indices for each of the compartments in this local genus symbol if it is associated to the prime p=2 (and raise an error for all other primes).

OUTPUT:

a list of non-negative integers

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import p_adic_symbol
sage: from sage.quadratic_forms.genera.genus import Genus_Symbol_p_adic_ring

sage: A = DiagonalQuadraticForm(ZZ, [1,2,3,4]).Hessian_matrix()
sage: p = 2
sage: G2 = Genus_Symbol_p_adic_ring(p, p_adic_symbol(A, p, 2)); G2
Genus symbol at 2:    [2^-2 4^1 8^1]_6
sage: G2.compartments()
[[0, 1, 2]]
det()

Returns the (\(p\)-part of the) determinant (square-class) of the Hessian matrix of the quadratic form (given by regarding the integral symmetric matrix which generated this genus symbol as the Gram matrix of \(Q\)) associated to this local genus symbol.

OUTPUT:

an integer

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import p_adic_symbol
sage: from sage.quadratic_forms.genera.genus import Genus_Symbol_p_adic_ring

sage: A = DiagonalQuadraticForm(ZZ, [1,2,3,4]).Hessian_matrix()
sage: p = 2
sage: G2 = Genus_Symbol_p_adic_ring(p, p_adic_symbol(A, p, 2)); G2
Genus symbol at 2:    [2^-2 4^1 8^1]_6
sage: G2.determinant()
128

sage: A = DiagonalQuadraticForm(ZZ, [1,2,3,4]).Hessian_matrix()
sage: p = 3
sage: G3 = Genus_Symbol_p_adic_ring(p, p_adic_symbol(A, p, 2)); G3
Genus symbol at 3:     1^3 3^-1
sage: G3.determinant()
3
determinant()

Returns the (\(p\)-part of the) determinant (square-class) of the Hessian matrix of the quadratic form (given by regarding the integral symmetric matrix which generated this genus symbol as the Gram matrix of \(Q\)) associated to this local genus symbol.

OUTPUT:

an integer

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import p_adic_symbol
sage: from sage.quadratic_forms.genera.genus import Genus_Symbol_p_adic_ring

sage: A = DiagonalQuadraticForm(ZZ, [1,2,3,4]).Hessian_matrix()
sage: p = 2
sage: G2 = Genus_Symbol_p_adic_ring(p, p_adic_symbol(A, p, 2)); G2
Genus symbol at 2:    [2^-2 4^1 8^1]_6
sage: G2.determinant()
128

sage: A = DiagonalQuadraticForm(ZZ, [1,2,3,4]).Hessian_matrix()
sage: p = 3
sage: G3 = Genus_Symbol_p_adic_ring(p, p_adic_symbol(A, p, 2)); G3
Genus symbol at 3:     1^3 3^-1
sage: G3.determinant()
3
dim()

Return the dimension of a quadratic form associated to this genus symbol.

OUTPUT:

an non-negative integer

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import p_adic_symbol
sage: from sage.quadratic_forms.genera.genus import Genus_Symbol_p_adic_ring

sage: A = DiagonalQuadraticForm(ZZ, [1,2,3,4]).Hessian_matrix()
sage: p = 2
sage: G2 = Genus_Symbol_p_adic_ring(p, p_adic_symbol(A, p, 2)); G2
Genus symbol at 2:    [2^-2 4^1 8^1]_6
sage: G2.dimension()
4

sage: A = DiagonalQuadraticForm(ZZ, [1,2,3,4]).Hessian_matrix()
sage: p = 3
sage: G3 = Genus_Symbol_p_adic_ring(p, p_adic_symbol(A, p, 2)); G3
Genus symbol at 3:     1^3 3^-1
sage: G3.dimension()
4
dimension()

Return the dimension of a quadratic form associated to this genus symbol.

OUTPUT:

an non-negative integer

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import p_adic_symbol
sage: from sage.quadratic_forms.genera.genus import Genus_Symbol_p_adic_ring

sage: A = DiagonalQuadraticForm(ZZ, [1,2,3,4]).Hessian_matrix()
sage: p = 2
sage: G2 = Genus_Symbol_p_adic_ring(p, p_adic_symbol(A, p, 2)); G2
Genus symbol at 2:    [2^-2 4^1 8^1]_6
sage: G2.dimension()
4

sage: A = DiagonalQuadraticForm(ZZ, [1,2,3,4]).Hessian_matrix()
sage: p = 3
sage: G3 = Genus_Symbol_p_adic_ring(p, p_adic_symbol(A, p, 2)); G3
Genus symbol at 3:     1^3 3^-1
sage: G3.dimension()
4
excess()

Returns the p-excess of the quadratic form whose Hessian matrix is the symmetric matrix A. When p = 2 the p-excess is called the oddity.

Warning

This normalization seems non-standard, and we should review this entire class to make sure that we have our doubling conventions straight throughout!

REFERENCE:

[Co1999] Conway and Sloane Book, 3rd edition, pp 370-371.

OUTPUT:

an integer

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import p_adic_symbol
sage: from sage.quadratic_forms.genera.genus import Genus_Symbol_p_adic_ring

sage: AC = diagonal_matrix(ZZ, [1,3,-3])
sage: p=2; Genus_Symbol_p_adic_ring(p, p_adic_symbol(AC, p, 2)).excess()
1
sage: p=3; Genus_Symbol_p_adic_ring(p, p_adic_symbol(AC, p, 2)).excess()
0
sage: p=5; Genus_Symbol_p_adic_ring(p, p_adic_symbol(AC, p, 2)).excess()
0
sage: p=7; Genus_Symbol_p_adic_ring(p, p_adic_symbol(AC, p, 2)).excess()
0
sage: p=11; Genus_Symbol_p_adic_ring(p, p_adic_symbol(AC, p, 2)).excess()
0

sage: AC = 2 * diagonal_matrix(ZZ, [1,3,-3])
sage: p=2; Genus_Symbol_p_adic_ring(p, p_adic_symbol(AC, p, 2)).excess()
1
sage: p=3; Genus_Symbol_p_adic_ring(p, p_adic_symbol(AC, p, 2)).excess()
0
sage: p=5; Genus_Symbol_p_adic_ring(p, p_adic_symbol(AC, p, 2)).excess()
0
sage: p=7; Genus_Symbol_p_adic_ring(p, p_adic_symbol(AC, p, 2)).excess()
0
sage: p=11; Genus_Symbol_p_adic_ring(p, p_adic_symbol(AC, p, 2)).excess()
0

sage: A = 2*diagonal_matrix(ZZ, [1,2,3,4])
sage: p=2; Genus_Symbol_p_adic_ring(p, p_adic_symbol(A, p, 2)).excess()
2
sage: p=3; Genus_Symbol_p_adic_ring(p, p_adic_symbol(A, p, 2)).excess()
6
sage: p=5; Genus_Symbol_p_adic_ring(p, p_adic_symbol(A, p, 2)).excess()
0
sage: p=7; Genus_Symbol_p_adic_ring(p, p_adic_symbol(A, p, 2)).excess()
0
sage: p=11; Genus_Symbol_p_adic_ring(p, p_adic_symbol(A, p, 2)).excess()
0
gram_matrix(check=True)

Return a gram matrix of a representative of this local genus.

INPUT:

  • check (default: True) – double check the result

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import p_adic_symbol
sage: from sage.quadratic_forms.genera.genus import Genus_Symbol_p_adic_ring
sage: A = DiagonalQuadraticForm(ZZ, [1,2,3,4]).Hessian_matrix()
sage: p = 2
sage: G2 = Genus_Symbol_p_adic_ring(p, p_adic_symbol(A, p, 2))
sage: G2.gram_matrix()
[2 0|0|0]
[0 6|0|0]
[---+-+-]
[0 0|4|0]
[---+-+-]
[0 0|0|8]
is_even()

Return if the underlying \(p\)-adic lattice is even.

If \(p\) is odd, every lattice is even.

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import LocalGenusSymbol
sage: M0 = matrix(ZZ,[1])
sage: G0 = LocalGenusSymbol(M0, 2)
sage: G0.is_even()
False
sage: G1 = LocalGenusSymbol(M0, 3)
sage: G1.is_even()
True
sage: M2 = matrix(ZZ,[2])
sage: G2 = LocalGenusSymbol(M2, 2)
sage: G2.is_even()
True
number_of_blocks()

Return the number of positive dimensional symbols/Jordan blocks.

OUTPUT:

A non-negative integer

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import p_adic_symbol
sage: from sage.quadratic_forms.genera.genus import Genus_Symbol_p_adic_ring

sage: A = DiagonalQuadraticForm(ZZ, [1,2,3,4]).Hessian_matrix()
sage: p = 2
sage: G2 = Genus_Symbol_p_adic_ring(p, p_adic_symbol(A, p, 2)); G2.symbol_tuple_list()
[[1, 2, 3, 1, 4], [2, 1, 1, 1, 1], [3, 1, 1, 1, 1]]
sage: G2.number_of_blocks()
3

sage: A = DiagonalQuadraticForm(ZZ, [1,2,3,4]).Hessian_matrix()
sage: p = 3
sage: G3 = Genus_Symbol_p_adic_ring(p, p_adic_symbol(A, p, 2)); G3.symbol_tuple_list()
[[0, 3, 1], [1, 1, -1]]
sage: G3.number_of_blocks()
2
prime()

Return the prime number \(p\) of this \(p\)-adic local symbol.

OUTPUT:

  • an integer

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import LocalGenusSymbol
sage: M1 = matrix(ZZ,[2])
sage: p = 2
sage: G0 = LocalGenusSymbol(M1, 2)
sage: G0.prime()
2
rank()

Return the dimension of a quadratic form associated to this genus symbol.

OUTPUT:

an non-negative integer

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import p_adic_symbol
sage: from sage.quadratic_forms.genera.genus import Genus_Symbol_p_adic_ring

sage: A = DiagonalQuadraticForm(ZZ, [1,2,3,4]).Hessian_matrix()
sage: p = 2
sage: G2 = Genus_Symbol_p_adic_ring(p, p_adic_symbol(A, p, 2)); G2
Genus symbol at 2:    [2^-2 4^1 8^1]_6
sage: G2.dimension()
4

sage: A = DiagonalQuadraticForm(ZZ, [1,2,3,4]).Hessian_matrix()
sage: p = 3
sage: G3 = Genus_Symbol_p_adic_ring(p, p_adic_symbol(A, p, 2)); G3
Genus symbol at 3:     1^3 3^-1
sage: G3.dimension()
4
symbol_tuple_list()

Return a copy of the underlying list of lists of integers defining the genus symbol.

OUTPUT:

a list of lists of integers

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import p_adic_symbol
sage: from sage.quadratic_forms.genera.genus import Genus_Symbol_p_adic_ring

sage: A = DiagonalQuadraticForm(ZZ, [1,2,3,4]).Hessian_matrix()
sage: p = 3
sage: G3 = Genus_Symbol_p_adic_ring(p, p_adic_symbol(A, p, 2)); G3
Genus symbol at 3:     1^3 3^-1
sage: G3.symbol_tuple_list()
[[0, 3, 1], [1, 1, -1]]
sage: type(G3.symbol_tuple_list())
<... 'list'>

sage: A = DiagonalQuadraticForm(ZZ, [1,2,3,4]).Hessian_matrix()
sage: p = 2
sage: G2 = Genus_Symbol_p_adic_ring(p, p_adic_symbol(A, p, 2)); G2
Genus symbol at 2:    [2^-2 4^1 8^1]_6
sage: G2.symbol_tuple_list()
[[1, 2, 3, 1, 4], [2, 1, 1, 1, 1], [3, 1, 1, 1, 1]]
sage: type(G2.symbol_tuple_list())
<... 'list'>
trains()

Compute the indices for each of the trains in this local genus symbol if it is associated to the prime p=2 (and raise an error for all other primes).

OUTPUT:

a list of non-negative integers

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import p_adic_symbol
sage: from sage.quadratic_forms.genera.genus import Genus_Symbol_p_adic_ring

sage: A = DiagonalQuadraticForm(ZZ, [1,2,3,4]).Hessian_matrix()
sage: p = 2
sage: G2 = Genus_Symbol_p_adic_ring(p, p_adic_symbol(A, p, 2)); G2
Genus symbol at 2:    [2^-2 4^1 8^1]_6
sage: G2.trains()
[[0, 1, 2]]
sage.quadratic_forms.genera.genus.LocalGenusSymbol(A, p)

Return the local symbol of \(A\) at the prime \(p\).

INPUT:

  • A – a symmetric, non-singular matrix with coefficients in \(\ZZ\)
  • p – a prime number

OUTPUT:

A Genus_Symbol_p_adic_ring object, encoding the Conway-Sloane genus symbol at \(p\) of the quadratic form whose Gram matrix is \(A\).

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import LocalGenusSymbol
sage: A = Matrix(ZZ, 2, 2, [1,1,1,2])
sage: LocalGenusSymbol(A, 2)
Genus symbol at 2:    [1^2]_2
sage: LocalGenusSymbol(A, 3)
Genus symbol at 3:     1^2

sage: A = Matrix(ZZ, 2, 2, [1,0,0,2])
sage: LocalGenusSymbol(A, 2)
Genus symbol at 2:    [1^1 2^1]_2
sage: LocalGenusSymbol(A, 3)
Genus symbol at 3:     1^-2
sage.quadratic_forms.genera.genus.basis_complement(B)

Given an echelonized basis matrix \(B\) (over a field), calculate a matrix whose rows form a basis complement (to the rows of \(B\)).

INPUT:

  • B – matrix over a field in row echelon form

OUTPUT:

a rectangular matrix over a field

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import basis_complement

sage: A = Matrix(ZZ, 2, 2, [1,1,1,1])
sage: B = A.kernel().echelonized_basis_matrix(); B
[ 1 -1]
sage: basis_complement(B)
[0 1]
sage.quadratic_forms.genera.genus.canonical_2_adic_compartments(genus_symbol_quintuple_list)

Given a \(2\)-adic local symbol (as the underlying list of quintuples) this returns a list of lists of indices of the genus_symbol_quintuple_list which are in the same compartment. A compartment is defined to be a maximal interval of Jordan components all (scaled) of type I (i.e. odd).

INPUT:

  • genus_symbol_quintuple_list – a quintuple of integers (with certain restrictions).

OUTPUT:

a list of lists of integers.

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import LocalGenusSymbol
sage: from sage.quadratic_forms.genera.genus import canonical_2_adic_compartments

sage: A = Matrix(ZZ, 2, 2, [1,1,1,2])
sage: G2 = LocalGenusSymbol(A, 2); G2.symbol_tuple_list()
[[0, 2, 1, 1, 2]]
sage: canonical_2_adic_compartments(G2.symbol_tuple_list())
[[0]]

sage: A = Matrix(ZZ, 2, 2, [1,0,0,2])
sage: G2 = LocalGenusSymbol(A, 2); G2.symbol_tuple_list()
[[0, 1, 1, 1, 1], [1, 1, 1, 1, 1]]
sage: canonical_2_adic_compartments(G2.symbol_tuple_list())
[[0, 1]]

sage: A = DiagonalQuadraticForm(ZZ, [1,2,3,4]).Hessian_matrix()
sage: G2 = LocalGenusSymbol(A, 2); G2.symbol_tuple_list()
[[1, 2, 3, 1, 4], [2, 1, 1, 1, 1], [3, 1, 1, 1, 1]]
sage: canonical_2_adic_compartments(G2.symbol_tuple_list())
[[0, 1, 2]]

sage: A = Matrix(ZZ, 2, 2, [2,1,1,2])
sage: G2 = LocalGenusSymbol(A, 2); G2.symbol_tuple_list()
[[0, 2, 3, 0, 0]]
sage: canonical_2_adic_compartments(G2.symbol_tuple_list())   ## No compartments here!
[]

Note

See [Co1999] Conway-Sloane 3rd edition, pp. 381-382 for definitions and examples.

sage.quadratic_forms.genera.genus.canonical_2_adic_reduction(genus_symbol_quintuple_list)

Given a \(2\)-adic local symbol (as the underlying list of quintuples) this returns a canonical \(2\)-adic symbol (again as a raw list of quintuples of integers) which has at most one minus sign per train and this sign appears on the smallest dimensional Jordan component in each train. This results from applying the “sign-walking” and “oddity fusion” equivalences.

INPUT:

  • genus_symbol_quintuple_list – a quintuple of integers (with certain restrictions)
  • compartments – a list of lists of distinct integers (optional)

OUTPUT:

a list of lists of distinct integers.

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import LocalGenusSymbol
sage: from sage.quadratic_forms.genera.genus import canonical_2_adic_reduction

sage: A = Matrix(ZZ, 2, 2, [1,1,1,2])
sage: G2 = LocalGenusSymbol(A, 2); G2.symbol_tuple_list()
[[0, 2, 1, 1, 2]]
sage: canonical_2_adic_reduction(G2.symbol_tuple_list())
[[0, 2, 1, 1, 2]]

sage: A = Matrix(ZZ, 2, 2, [1,0,0,2])
sage: G2 = LocalGenusSymbol(A, 2); G2.symbol_tuple_list()
[[0, 1, 1, 1, 1], [1, 1, 1, 1, 1]]
sage: canonical_2_adic_reduction(G2.symbol_tuple_list())   ## Oddity fusion occurred here!
[[0, 1, 1, 1, 2], [1, 1, 1, 1, 0]]

sage: A = DiagonalQuadraticForm(ZZ, [1,2,3,4]).Hessian_matrix()
sage: G2 = LocalGenusSymbol(A, 2); G2.symbol_tuple_list()
[[1, 2, 3, 1, 4], [2, 1, 1, 1, 1], [3, 1, 1, 1, 1]]
sage: canonical_2_adic_reduction(G2.symbol_tuple_list())   ## Oddity fusion occurred here!
[[1, 2, -1, 1, 6], [2, 1, 1, 1, 0], [3, 1, 1, 1, 0]]

sage: A = Matrix(ZZ, 2, 2, [2,1,1,2])
sage: G2 = LocalGenusSymbol(A, 2); G2.symbol_tuple_list()
[[0, 2, 3, 0, 0]]
sage: canonical_2_adic_reduction(G2.symbol_tuple_list())
[[0, 2, -1, 0, 0]]

Note

See [Co1999] Conway-Sloane 3rd edition, pp. 381-382 for definitions and examples.

Todo

Add an example where sign walking occurs!

sage.quadratic_forms.genera.genus.canonical_2_adic_trains(genus_symbol_quintuple_list, compartments=None)

Given a \(2\)-adic local symbol (as the underlying list of quintuples) this returns a list of lists of indices of the genus_symbol_quintuple_list which are in the same train. A train is defined to be a maximal interval of Jordan components so that at least one of each adjacent pair (allowing zero-dimensional Jordan components) is (scaled) of type I (i.e. odd). Note that an interval of length one respects this condition as there is no pair in this interval. In particular, every Jordan component is part of a train.

INPUT:

  • genus_symbol_quintuple_list – a quintuple of integers (with certain restrictions).
  • compartments – this argument is deprecated

OUTPUT:

a list of lists of distinct integers.

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import LocalGenusSymbol
sage: from sage.quadratic_forms.genera.genus import canonical_2_adic_compartments
sage: from sage.quadratic_forms.genera.genus import canonical_2_adic_trains

sage: A = Matrix(ZZ, 2, 2, [1,1,1,2])
sage: G2 = LocalGenusSymbol(A, 2); G2.symbol_tuple_list()
[[0, 2, 1, 1, 2]]
sage: canonical_2_adic_trains(G2.symbol_tuple_list())
[[0]]

sage: A = Matrix(ZZ, 2, 2, [1,0,0,2])
sage: G2 = LocalGenusSymbol(A, 2); G2.symbol_tuple_list()
[[0, 1, 1, 1, 1], [1, 1, 1, 1, 1]]
sage: canonical_2_adic_compartments(G2.symbol_tuple_list())
[[0, 1]]

sage: A = DiagonalQuadraticForm(ZZ, [1,2,3,4]).Hessian_matrix()
sage: G2 = LocalGenusSymbol(A, 2); G2.symbol_tuple_list()
[[1, 2, 3, 1, 4], [2, 1, 1, 1, 1], [3, 1, 1, 1, 1]]
sage: canonical_2_adic_trains(G2.symbol_tuple_list())
[[0, 1, 2]]

sage: A = Matrix(ZZ, 2, 2, [2,1,1,2])
sage: G2 = LocalGenusSymbol(A, 2); G2.symbol_tuple_list()
[[0, 2, 3, 0, 0]]
sage: canonical_2_adic_trains(G2.symbol_tuple_list())
[[0]]
sage: symbol = [[0, 1,  1, 1, 1],[1, 2, -1, 0, 0],[2, 1,  1, 1, 1],[3, 1,  1, 1, 1],[4, 1,  1, 1, 1],[5, 2, -1, 0, 0],[7, 1,  1, 1, 1],[10, 1, 1, 1, 1],[11, 1, 1, 1, 1],[12, 1, 1, 1, 1]]
sage: canonical_2_adic_trains(symbol)
[[0, 1, 2, 3, 4, 5], [6], [7, 8, 9]]

Check that trac ticket #24818 is fixed:

sage: symbol = [[0, 1,  1, 1, 1],[1, 3, 1, 1, 1]]
sage: canonical_2_adic_trains(symbol)
[[0, 1]]

Note

See [Co1999], pp. 381-382 for definitions and examples.

sage.quadratic_forms.genera.genus.genera(sig_pair, determinant, max_scale=None, even=False)

Return a list of all global genera with the given conditions.

Here a genus is called global if it is non-empty.

INPUT:

  • sig_pair – a pair of non-negative integers giving the signature
  • determinant – an integer; the sign is ignored
  • max_scale – (default: None) an integer; the maximum scale of a jordan block
  • even – boolean (default: False)

OUTPUT:

A list of all (non-empty) global genera with the given conditions.

EXAMPLES:

sage: QuadraticForm.genera((4,0), 125, even=True)
[Genus of
None
Signature:  (4, 0)
Genus symbol at 2:    1^-4
Genus symbol at 5:     1^1 5^3, Genus of
None
Signature:  (4, 0)
Genus symbol at 2:    1^-4
Genus symbol at 5:     1^-2 5^1 25^-1, Genus of
None
Signature:  (4, 0)
Genus symbol at 2:    1^-4
Genus symbol at 5:     1^2 5^1 25^1, Genus of
None
Signature:  (4, 0)
Genus symbol at 2:    1^-4
Genus symbol at 5:     1^3 125^1]
sage.quadratic_forms.genera.genus.is_2_adic_genus(genus_symbol_quintuple_list)

Given a \(2\)-adic local symbol (as the underlying list of quintuples) check whether it is the \(2\)-adic symbol of a \(2\)-adic form.

INPUT:

  • genus_symbol_quintuple_list – a quintuple of integers (with certain restrictions).

OUTPUT:

boolean

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import LocalGenusSymbol, is_2_adic_genus

sage: A = Matrix(ZZ, 2, 2, [1,1,1,2])
sage: G2 = LocalGenusSymbol(A, 2)
sage: is_2_adic_genus(G2.symbol_tuple_list())
True

sage: A = Matrix(ZZ, 2, 2, [1,1,1,2])
sage: G3 = LocalGenusSymbol(A, 3)
sage: is_2_adic_genus(G3.symbol_tuple_list())  ## This raises an error
Traceback (most recent call last):
...
TypeError: The genus symbols are not quintuples, so it's not a genus symbol for the prime p=2.

sage: A = Matrix(ZZ, 2, 2, [1,0,0,2])
sage: G2 = LocalGenusSymbol(A, 2)
sage: is_2_adic_genus(G2.symbol_tuple_list())
True
sage.quadratic_forms.genera.genus.is_GlobalGenus(G)

Return if \(G\) represents the genus of a global quadratic form or lattice.

INPUT:

OUTPUT:

  • boolean

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import is_GlobalGenus
sage: A = Matrix(ZZ, 2, 2, [1,1,1,2])
sage: G = Genus(A)
sage: is_GlobalGenus(G)
True
sage: G=Genus(matrix.diagonal([2,2,2,2]))
sage: G._local_symbols[0]._symbol=[[0,2,3,0,0],[1,2,5,1,0]]
sage: G._representative=None
sage: is_GlobalGenus(G)
False
sage.quadratic_forms.genera.genus.is_even_matrix(A)

Determines if the integral symmetric matrix \(A\) is even (i.e. represents only even numbers). If not, then it returns the index of an odd diagonal entry. If it is even, then we return the index -1.

INPUT:

  • A – symmetric integer matrix

OUTPUT:

a pair of the form (boolean, integer)

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import is_even_matrix

sage: A = Matrix(ZZ, 2, 2, [1,1,1,1])
sage: is_even_matrix(A)
(False, 0)

sage: A = Matrix(ZZ, 2, 2, [2,1,1,2])
sage: is_even_matrix(A)
(True, -1)
sage.quadratic_forms.genera.genus.p_adic_symbol(A, p, val)

Given a symmetric matrix \(A\) and prime \(p\), return the genus symbol at \(p\).

Todo

Some description of the definition of the genus symbol.

INPUT:

  • A – symmetric matrix with integer coefficients
  • p – prime number
  • val – non-negative integer; valuation of the maximal elementary divisor of \(A\) needed to obtain enough precision. Calculation is modulo \(p\) to the val+3.

OUTPUT:

a list of lists of integers

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import p_adic_symbol

sage: A = DiagonalQuadraticForm(ZZ, [1,2,3,4]).Hessian_matrix()
sage: p_adic_symbol(A, 2, 2)
[[1, 2, 3, 1, 4], [2, 1, 1, 1, 1], [3, 1, 1, 1, 1]]

sage: p_adic_symbol(A, 3, 1)
[[0, 3, 1], [1, 1, -1]]
sage.quadratic_forms.genera.genus.signature_pair_of_matrix(A)

Computes the signature pair \((p, n)\) of a non-degenerate symmetric matrix, where

  • \(p\) is the number of positive eigenvalues of \(A\)
  • \(n\) is the number of negative eigenvalues of \(A\)

INPUT:

  • A – symmetric matrix (assumed to be non-degenerate)

OUTPUT:

  • \((p, n)\) – a pair (tuple) of integers.

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import signature_pair_of_matrix

sage: A = Matrix(ZZ, 2, 2, [-1,0,0,3])
sage: signature_pair_of_matrix(A)
(1, 1)

sage: A = Matrix(ZZ, 2, 2, [-1,1,1,7])
sage: signature_pair_of_matrix(A)
(1, 1)

sage: A = Matrix(ZZ, 2, 2, [3,1,1,7])
sage: signature_pair_of_matrix(A)
(2, 0)

sage: A = Matrix(ZZ, 2, 2, [-3,1,1,-11])
sage: signature_pair_of_matrix(A)
(0, 2)


sage: A = Matrix(ZZ, 2, 2, [1,1,1,1])
sage: signature_pair_of_matrix(A)
Traceback (most recent call last):
...
ArithmeticError: given matrix is not invertible
sage.quadratic_forms.genera.genus.split_odd(A)

Given a non-degenerate Gram matrix \(A (\mod 8)\), return a splitting [u] + B such that u is odd and \(B\) is not even.

INPUT:

  • A – an odd symmetric matrix with integer coefficients (which admits a splitting as above).

OUTPUT:

a pair (u, B) consisting of an odd integer \(u\) and an odd integral symmetric matrix \(B\).

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import is_even_matrix
sage: from sage.quadratic_forms.genera.genus import split_odd

sage: A = Matrix(ZZ, 2, 2, [1,2,2,3])
sage: is_even_matrix(A)
(False, 0)
sage: split_odd(A)
(1, [-1])

sage: A = Matrix(ZZ, 2, 2, [1,2,2,5])
sage: split_odd(A)
(1, [1])

sage: A = Matrix(ZZ, 2, 2, [1,1,1,1])
sage: is_even_matrix(A)
(False, 0)
sage: split_odd(A)      ## This fails because no such splitting exists. =(
Traceback (most recent call last):
...
RuntimeError: The matrix A does not admit a non-even splitting.

sage: A = Matrix(ZZ, 2, 2, [1,2,2,6])
sage: split_odd(A)      ## This fails because no such splitting exists. =(
Traceback (most recent call last):
...
RuntimeError: The matrix A does not admit a non-even splitting.
sage.quadratic_forms.genera.genus.trace_diag_mod_8(A)

Return the trace of the diagonalised form of \(A\) of an integral symmetric matrix which is diagonalizable \(\mod 8\). (Note that since the Jordan decomposition into blocks of size \(<=\) 2 is not unique here, this is not the same as saying that \(A\) is always diagonal in any \(2\)-adic Jordan decomposition!)

INPUT:

  • A – symmetric matrix with coefficients in \(\ZZ\) which is odd in \(\ZZ/2\ZZ\) and has determinant not divisible by \(8\).

OUTPUT:

an integer

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import is_even_matrix
sage: from sage.quadratic_forms.genera.genus import split_odd
sage: from sage.quadratic_forms.genera.genus import trace_diag_mod_8

sage: A = Matrix(ZZ, 2, 2, [1,2,2,3])
sage: is_even_matrix(A)
(False, 0)
sage: split_odd(A)
(1, [-1])
sage: trace_diag_mod_8(A)
0

sage: A = Matrix(ZZ, 2, 2, [1,2,2,5])
sage: split_odd(A)
(1, [1])
sage: trace_diag_mod_8(A)
2
sage.quadratic_forms.genera.genus.two_adic_symbol(A, val)

Given a symmetric matrix \(A\) and prime \(p\), return the genus symbol at \(p\).

The genus symbol of a component 2^m*f is of the form (m,n,s,d[,o]), where

  • m = valuation of the component
  • n = dimension of f
  • d = det(f) in {1,3,5,7}
  • s = 0 (or 1) if even (or odd)
  • o = oddity of f (= 0 if s = 0) in \(Z/8Z\)

INPUT:

  • A – symmetric matrix with integer coefficients, non-degenerate
  • val – non-negative integer; valuation of maximal \(2\)-elementary divisor

OUTPUT:

a list of lists of integers (representing a Conway-Sloane \(2\)-adic symbol)

EXAMPLES:

sage: from sage.quadratic_forms.genera.genus import two_adic_symbol

sage: A = diagonal_matrix(ZZ, [1,2,3,4])
sage: two_adic_symbol(A, 2)
[[0, 2, 3, 1, 4], [1, 1, 1, 1, 1], [2, 1, 1, 1, 1]]