# Group algebras¶

This functionality has been moved to sage.categories.algebra_functor.

sage.algebras.group_algebra.GroupAlgebra(G, R=Integer Ring)

Return the group algebra of $$G$$ over $$R$$.

INPUT:

• $$G$$ – a group
• $$R$$ – (default: $$\ZZ$$) a ring

EXAMPLES:

The group algebra $$A=RG$$ is the space of formal linear combinations of elements of $$G$$ with coefficients in $$R$$:

sage: G = DihedralGroup(3)
sage: R = QQ
sage: A = GroupAlgebra(G, R); A
Algebra of Dihedral group of order 6 as a permutation group over Rational Field
sage: a = A.an_element(); a
() + (1,2) + 3*(1,2,3) + 2*(1,3,2)


This space is endowed with an algebra structure, obtained by extending by bilinearity the multiplication of $$G$$ to a multiplication on $$RG$$:

sage: A in Algebras
True
sage: a * a
14*() + 5*(2,3) + 2*(1,2) + 10*(1,2,3) + 13*(1,3,2) + 5*(1,3)


GroupAlgebra() is just a short hand for a more general construction that covers, e.g., monoid algebras, additive group algebras and so on:

sage: G.algebra(QQ)
Algebra of Dihedral group of order 6 as a permutation group over Rational Field

sage: GroupAlgebra(G,QQ) is G.algebra(QQ)
True

sage: M = Monoids().example(); M
An example of a monoid:
the free monoid generated by ('a', 'b', 'c', 'd')
sage: M.algebra(QQ)
Algebra of An example of a monoid: the free monoid generated by ('a', 'b', 'c', 'd')
over Rational Field


See the documentation of sage.categories.algebra_functor for details.

class sage.algebras.group_algebra.GroupAlgebra_class(R, basis_keys=None, element_class=None, category=None, prefix=None, names=None, **kwds)